Ciro Santilli @cirosantilli 34

# List of living Nobel Laureates sorted by date of birth 
SELECT DISTINCT ?recipient ?recipientLabel $birthDate ?awardLabel ?nobelDate ?educatedAtLabel ?academicDegree ?academicDegreeLabel ?doctorateDate
WHERE { 
  ?recipient wdt:P31 wd:Q5 ; # recepient is human (Peace prize can go to organizations) 
             wdt:P569 ?birthDate ; 
             p:P166 ?awardStat . # recepient was awarded something 
  ?awardStat ps:P166 ?award .
  ?award wdt:P279* wd:Q7191 . # received any subclass of nobel prize (physics, chemistry, etc.) 
  ?awardStat pq:P585 ?nobelDate .
  ?recipient p:P69 ?recipientEducatedAt .
  ?recipientEducatedAt ps:P69 ?educatedAt .
  ?recipientEducatedAt pq:P512 ?academicDegree .
  ?academicDegree wdt:P279* wd:Q849697 .
  OPTIONAL{ ?recipientEducatedAt pq:P582 ?doctorateDate . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . } 
} 
ORDER BY ASC(?birthDate) ASC(?nobelDate) ASC(?awardLabel)

SELECT
  ?currency
  (GROUP_CONCAT(DISTINCT ?currencyIsoCode; SEPARATOR=", ") AS ?currencyIsoCodes)
  ?currencyLabel
  (GROUP_CONCAT(DISTINCT ?countryLabel; SEPARATOR=", ") AS ?countries)
WHERE {
  ?country wdt:P31/wdt:P279* wd:Q6256. # is country
  ?country p:P38 ?countryHasCurrency.
  ?countryHasCurrency ps:P38 ?currency.
  ?countryHasCurrency wikibase:rank ?countryHasCurrencyRank.
  OPTIONAL {
    ?currency p:P498 ?currencyHasIsoCode.
    ?currencyHasIsoCode ps:P498 ?currencyIsoCode.
  }
  FILTER NOT EXISTS {?country wdt:P576 ?countryAbolished}
  FILTER NOT EXISTS {?currency wdt:P576 ?currencyAbolished}
  FILTER NOT EXISTS {?currency wdt:P582 ?currencyEndTime}
  FILTER NOT EXISTS {?countryHasCurrency pq:P582 ?countryHasCurrencyEndtime}
  FILTER (?countryHasCurrencyRank != wikibase:DeprecatedRank)
  FILTER (!bound(?currencyHasIsoCode) || ?currencyHasIsoCode != wikibase:DeprecatedRank)
  # TODO makes query take timeout? Why? Needed to exclude PLZ.
  FILTER NOT EXISTS {?currencyHasIsoCode pq:P582 ?currencyHasIsoCodeEndtime}
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?currency rdfs:label ?currencyLabel .
    ?country rdfs:label ?countryLabel .
  }
}
GROUP BY ?currency ?currencyLabel
ORDER BY ?currencyIsoCodes ?currencyLabel